{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    tailwind-ctp.url = "git+https://git.jojodev.com/jolheiser/tailwind-ctp";
    tailwind-ctp-lsp.url = "git+https://git.jojodev.com/jolheiser/tailwind-ctp-intellisense";
  };

  outputs =
    {
      self,
      flake-utils,
      nixpkgs,
      tailwind-ctp,
      tailwind-ctp-lsp,
    }@inputs:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        tailwind-ctp = inputs.tailwind-ctp.packages.${system}.default;
        tailwind-ctp-lsp = inputs.tailwind-ctp-lsp.packages.${system}.default;
      in
      {
        packages.default = pkgs.buildGoModule {
          pname = "jolheiser.com";
          version = "site";
          src = ./.;
          vendorHash = nixpkgs.lib.fileContents ./go.mod.sri;
          nativeBuildInputs = [ tailwind-ctp ];
          excludedPackages = ".";
          postBuild = ''
            go generate
            mv dist $out
          '';
        };
        devShells.default = pkgs.mkShell {
          nativeBuildInputs = with pkgs; [
            go
            tailwind-ctp
            tailwind-ctp-lsp
            vscode-langservers-extracted
          ];
        };
      }
    );
}