{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    tailwind-ctp.url = "git+https://git.jojodev.com/jolheiser/tailwind-ctp";
    tailwind-ctp-lsp.url = "git+https://git.jojodev.com/jolheiser/tailwind-ctp-intellisense";
  };

  outputs =
    inputs:
    let
      systems = [
        "x86_64-linux"
        "i686-linux"
        "x86_64-darwin"
        "aarch64-linux"
        "armv6l-linux"
        "armv7l-linux"
      ];
      forAllSystems =
        f:
        inputs.nixpkgs.lib.genAttrs systems (
          system:
          f {
            pkgs = import inputs.nixpkgs {
              inherit system;
              overlays = [ inputs.self.overlays.default ];
            };
          }
        );
    in
    {
      overlays.default = final: prev: {
        tailwind-ctp = inputs.tailwind-ctp.packages.${prev.system}.default;
        tailwind-ctp-lsp = inputs.tailwind-ctp-lsp.packages.${prev.system}.default;
      };
      packages = forAllSystems (
        { pkgs }:
        {
          default = pkgs.buildGoModule {
            pname = "jolheiser.com";
            version = "site";
            src = ./.;
            vendorHash = inputs.nixpkgs.lib.fileContents ./go.mod.sri;
            nativeBuildInputs = [ inputs.tailwind-ctp ];
            excludedPackages = ".";
            postBuild = ''
              go generate
              mv dist $out
            '';
          };
        }
      );
      devShells = forAllSystems (
        { pkgs }:
        {
          default = pkgs.mkShell {
            nativeBuildInputs = with pkgs; [
              go
              tailwind-ctp
              tailwind-ctp-lsp
              vscode-langservers-extracted
            ];
          };
        }
      );
    };
}