{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    templ = {
      url = "github:a-h/templ";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    tailwind-ctp = {
      url = "git+https://git.jojodev.com/jolheiser/tailwind-ctp";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    tailwind-ctp-lsp = {
      url = "git+https://git.jojodev.com/jolheiser/tailwind-ctp-intellisense";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    flake-utils,
    nixpkgs,
    templ,
    tailwind-ctp,
    tailwind-ctp-lsp,
  } @ inputs:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};
        tailwind-ctp = inputs.tailwind-ctp.packages.${system}.default;
        tailwind-ctp-lsp = inputs.tailwind-ctp-lsp.packages.${system}.default;
        templ = inputs.templ.packages.${system}.templ;
      in {
        packages.default = pkgs.buildGoModule {
          pname = "jolheiser.com";
          version = "site";
          src = ./.;
          vendorHash = nixpkgs.lib.fileContents ./go.mod.sri;
          nativeBuildInputs = [templ tailwind-ctp];
          excludedPackages = ".";
          postBuild = ''
            go generate
            mv dist $out
          '';
        };
        devShells.default = pkgs.mkShell {
          nativeBuildInputs = with pkgs; [
            go
            templ
            tailwind-ctp
            tailwind-ctp-lsp
            vscode-langservers-extracted
          ];
        };
      }
    );
}
