{
  description = "jolheiser's nixos config";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    agenix.url = "github:ryantm/agenix";
    agenix.inputs = {
      nixpkgs.follows = "nixpkgs";
      darwin.follows = "";
    };
    flake-utils.url = "github:numtide/flake-utils";
    git-agecrypt.url = "github:vlaci/git-agecrypt";
    git-agecrypt.inputs.nixpkgs.follows = "nixpkgs";
    git-agecrypt.inputs.flake-utils.follows = "flake-utils";

    nur.url = "github:nix-community/nur";
    jolheiser-nur.url = "git+https://git.jojodev.com/jolheiser/nur";
  };

  outputs = {
    self,
    nixpkgs,
    home-manager,
    agenix,
    git-agecrypt,
    jolheiser-nur,
    ...
  } @ inputs: let
    overlays = final: prev: {
      nur = import inputs.nur {
        nurpkgs = prev;
        pkgs = prev;
        repoOverrides = {
          jolheiser = import jolheiser-nur {pkgs = prev;};
        };
      };
    };
    commonConfig = {
      config,
      pkgs,
      ...
    }: let
      userSecret = path: {
        file = path;
        owner = username;
      };
    in {
      config = {
        nixpkgs.overlays = [overlays git-agecrypt.overlay];
        home-manager = {
          useGlobalPkgs = true;
          useUserPackages = true;
          users.${username}.imports = [./apps];
          extraSpecialArgs = {
            flakePath = "/home/${username}/.config/nixpkgs";
          };
        };
        age.secrets = {
          ssh-config = userSecret ./secrets/shared/ssh-config.age;
          ssh-config-work = userSecret ./secrets/shared/ssh-config-work.age;
          spotify-pw = userSecret ./secrets/shared/spotify-pw.age;
          irc-pw = userSecret ./secrets/shared/irc-pw.age;
        };
      };
    };
    username = "jolheiser";
  in
    {
      nixosConfigurations = {
        "chai" = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [
            home-manager.nixosModules.home-manager
            agenix.nixosModules.default
            ./machines/common
            ./machines/chai
            commonConfig
            ({pkgs, ...}: {
              home-manager.users.${username}.programs.git.package = pkgs.gitSVN;
            })
          ];
        };
        "matcha" = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [
            home-manager.nixosModules.home-manager
            agenix.nixosModules.default
            ./machines/common
            ./machines/matcha
            commonConfig
          ];
        };
      };
    }
    // inputs.flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};
    in {
      devShells.default = pkgs.mkShell {
        nativeBuildInputs = [
          agenix.packages.${system}.agenix
        ];
      };
    });
}